MS-DOS Startdisketten/ Bootmenü für alten P1 Rechner

[Thunderbird 1400]

Hallo Leute!

Ich habe mir bei eBay einen alten Nostalgie-Rechner zusammengekauft, um ein paar alte DOS-Spiele zu zocken usw.
Es ist ein P1 166 MMX, wieviel Ram der hat, weiß ich noch nicht. Auf jeden Fall hat er eine 1,6 GB Festplatte, also genug Platz für alte DOS-Games :-)

Ich werde erstmal DOS 6.22 und Win 3.11 installieren, und dann geht's ans Konfigurieren.

Deshalb wollte ich mal fragen, ob ihr Seiten kennt, wo man MS-DOS Startdisketten bekommt, also zum Beispiel für verschiedene Spielekonfigurationen.
Kann mich noch schwach an meine 486'er Zeit erinnern, da gab's ja Spiele, die EMM-Speicher brauchen usw.
Und natürlich CD-Rom und Maustreiber.

Am besten wären Config.sys/ Autoexec.bat Files mit so einem Auswahlmenü für verschiedene Speicher-Configs, mit und ohne CD-Rom usw. Sowas hatte ich mir damals auch zusammengebastelt, um nicht von Diskette booten zu müssen.

Hat vielleicht jemand sowas?

[macom]

Hi,

ist zwar nicht ganz was du suchst, aber schau mal nach, vielleicht ist ja was dabei....

http://www.bootdisk.com/


mfG
macom

[BigBrain]

Original geschrieben von Thunderbird 1400
...Am besten wären Config.sys/ Autoexec.bat Files mit so einem Auswahlmenü für verschiedene Speicher-Configs, mit und ohne CD-Rom usw. Sowas hatte ich mir damals auch zusammengebastelt, um nicht von Diskette booten zu müssen.
äussere deine genauen wünsche & ich hack dir ein erste-sahne-bootmenü für das msDOSe zusammen. ;D
alternativ kann ich dir mal das skelett einer msDOSen-gamerkiste raufbeamen. ;D

falls erwünscht -> PN. antwort kann 'ne weile dauern; hab ferien & der inet zugriff ist leider nicht gewährleistet :-[ sche..s urlaub ;)

mfg juerg(BigBrain) aka bezwinger der monster msDOSen mega batch dateien.

[Rocketarena]

Original geschrieben von BigBrain
äussere deine genauen wünsche & ich hack dir ein erste-sahne-bootmenü für das msDOSe zusammen. ;D
alternativ kann ich dir mal das skelett einer msDOSen-gamerkiste raufbeamen. ;D

falls erwünscht -> PN. antwort kann 'ne weile dauern; hab ferien & der inet zugriff ist leider nicht gewährleistet :-[ sche..s urlaub ;)

mfg juerg(BigBrain) aka bezwinger der monster msDOSen mega batch dateien.

Wäre toll, wenn Du mir sowas dann auch zur Verfügung stellen könntest, damit ichs auf meiner HP www.retropc.de anderen Usern zum Download anbieten kann!! Selbstvertändlich wirst Du dafür mit einem Dankeschön auf der Seite verewigt :)

[BigBrain]

Original geschrieben von Rocketarena
Wäre toll, wenn Du mir sowas dann auch zur Verfügung stellen könntest, damit ichs auf meiner HP www.retropc.de anderen Usern zum Download anbieten kann!! Selbstvertändlich wirst Du dafür mit einem Dankeschön auf der Seite verewigt :)
okidoki. sobald ich das zeug zusammengehackt hab, stell ich es hier in diesem thread rein. wenn das copy&paste zuviel mühe macht, sende ich das zeug auch als ZIP an eine mailaddi...

mfg juerg(BigBrain)

[BigBrain]

urgs... zum glück sind meine ferien vorbei... ;D

hier ist der link (http://uq.no-ip.com/msDOSe/msDOSen.zip) zum ZIP archiv. enthält das grundgerüst für das bootmenü. funzt ab ms-dos 6.0

ach, ihr müsst leider im "besitz" (*g* man kann sich ja das zeug organisieren bzw. geeignete *dealer* angehn) von ms-dos 6.0 sein; sowegen dem lizenzsche..s ;D

wenn ihr nur die autoexec.bat bzw die config.sys wollt
autoexec (http://uq.no-ip.com/msDOSe/autoexec.bat)
config (http://uq.no-ip.com/msDOSe/config.sys)

mfg juerg(BigBrain)

autoexec.bat

@ECHO OFF
REM
REM ----- Umgebungsvariable PATH setzen ---------------------------------------
CALL C:\DOS\BAT\SOLLPATH.BAT
REM ----- Andere Umgebungsvariablen setzen ------------------------------------
SET TEMP=C:\TEMP
SET TMP=C:\TEMP
REM
REM Fuer SoundBlaster Karte
SET SOUND=C:\DOS\DRIVER\SBPRO
SET BLASTER=A220 I7 D1 T4
REM ----- Diverses ------------------------------------------------------------
VERIFY OFF
PROMPT $P$G
REM Tastatur-Treiber wird in den hohen Speicherbereich geladen (LH).
REM Achtung! Ist der "SwissGerman" Treiber! (SG)
LH KEYB SG,,C:\DOS\KEYBOARD.SYS
REM ----- SBPro Init ----------------------------------------------------------
REM SoundBlaster Initialisierung
C:\DOS\DRIVER\SBPRO\SBP-SET /M:12 /VOC:12 /CD:12 /FM:12 > nul
REM ----- MOUSE Treiber -------------------------------------------------------
REM Der Maus-Treiber wird in den hohen Speicherbereich geladen (LH).
REM Die bildschirmausgabe des Maus-Treibers wird in das Null-Device
REM umgeleitet (> nul)
LH C:\DOS\DRIVER\MOUSE.COM > nul

GOTO %config%

:WINS
PATH=C:\WIN311;%PATH%
rem C:\WIN311\SMARTDRV.EXE
rem LH C:\WIN311\net start
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:ASPICD0 /M:12 /L:F > nul
WIN
GOTO end

:MSDOS2S
CALL netup.bat
PATH=C:\WIN311;%PATH%
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:ASPICD0 /M:12 /L:F > nul
GOTO end

:MSDOS0S
:MSDOS1S
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:ASPICD0 /M:12 /L:F > nul
GOTO end

:WINI
PATH=C:\WIN311;%PATH%
rem C:\WIN311\SMARTDRV.EXE
rem LH C:\WIN311\net start
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:IDECD0 /M:12 /L:F > nul
WIN
GOTO end

:MSDOS2I
CALL netup.bat
PATH=C:\WIN311;%PATH%
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:IDECD0 /M:12 /L:F > nul
GOTO end

:MSDOS0I
:MSDOS1I
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:IDECD0 /M:12 /L:F > nul
GOTO end

:MSDOS1I
REM ----- CD-ROM Treiber ------------------------------------------------------
LH C:\WIN311\MSCDEX.EXE /S /D:IDECD0 /M:12 /L:F > nul
C:\DOS\BAT\SKY.BAT

:end

REM ----- Diverses ------------------------------------------------------------
REM Eigentlich unnoetiges Geraffel
REM
rem C:\DOS\SMARTDRV.EXE /X
rem MODE CON CODEPAGE PREPARE=((850) C:\DOS\EGA.CPI)
rem MODE CON CODEPAGE SELECT=850


config.sys

[menu]
menuitem=MSDOS0S, MS-DOS Kommandozeile mit SCSI CD-ROM
menuitem=MSDOS1S, MS-DOS Kommandozeile mit EMS/SCSI CD-ROM
menuitem=MSDOS2S, MS-DOS Kommandozeile mit Netzwerk/SCSI CD-ROM
menuitem=MSDOS0I, MS-DOS Kommandozeile mit IDE(ATAPI) CD-ROM
menuitem=MSDOS1I, MS-DOS Kommandozeile mit EMS/IDE(ATAPI) CD-ROM
menuitem=MSDOS2I, MS-DOS Kommandozeile mit Netzwerk/IDE(ATAPI) CD-ROM
menuitem=MSDOS3I, SkyMenu EMS/IDE(ATAPI) CD-ROM
menuitem=WINS, Windows 3.11 mit CD SCSI
menuitem=WINI, Windows 3.11 mit IDE(ATAPI) CD-ROM

REM
REM Kommandostruktur für Menüauswahl im CONFIG.SYS
REM
REM menuitem=IDENTIFIKATOR, MENUBEZEICHNUG
REM
REM

REM ***** Definition der INCLUDE Zeilen ***************************************

[HIMEM]
REM ----- High Memory Treiber -------------------------------------------------
DEVICE=C:\DOS\HIMEM.SYS
DOS=UMB,HIGH

[EMS]
REM ----- EMS Memory Treiber --------------------------------------------------
REM EMM386 wird in den hohen Speicherbereich geladen (DEVICEHIGH)
REM 4096KB EMS (4096)
REM Hoher Speicherbereich wird zu den normalen 640KB gebunden (RAM)
REM Start des EMS-Fensters gleich nach dem VGA BIOS (FRAME=CC00)
REM Verwendet zusätzlich einen Speicherbereich hohen Speicherbereich
REM (/I=E000-F7FF)
REM
REM Unter Umständen müssen die Startadresse bzw. der zusätzliche
REM Speicherbereich auf Ihrem PC angepasst werden, da Ihr PC
REM möglicherweise ein grösseres VGB BIOS bzw. ein grösseres BIOS
REM besitzt.
REM
DEVICEHIGH=C:\DOS\EMM386.EXE 4096 RAM FRAME=CC00 /I=E000-F7FF

[NOEMS]
REM ----- EMS Memory Treiber --------------------------------------------------
REM EMM386-Treiber wird in den hohen Speicherbereich geladen (DEVICEHIGH)
REM Kein EMS (NOEMS)
REM Hoher Speicherbereich wird zu den normalen 640KB gebunden (RAM)
REM Verwendet zusätzlich einen Speicherbereich hohen Speicherbereich
REM (/I=E000-F7FF)
REM
DEVICEHIGH=C:\DOS\EMM386.EXE NOEMS RAM /I=E000-F7FF

[ASPI]
REM ----- SCSI ASPI Treiber ---------------------------------------------------
REM SCSI ASPI-Treiber für Adaptec Hostkontroller wird in den hohen
REM Speicherbereich geladen (DEVICEHIGH)
REM AHA-1542 -> ASPI4DOS.SYS
REM AHA-2940 -> ASPI8DOS.SYS
REM
REM Momentan ist der AHA-1542 deaktiviert (rem DEVIC...)
REM
rem DEVICEHIGH=C:\DOS\DRIVER\SCSI\ASPI4DOS.SYS /D /P230
DEVICEHIGH=C:\DOS\DRIVER\SCSI\ASPI8DOS.SYS
REM
REM ASPI-Treiber für Harddisks wird in den hohen Speicherbereich
REM geladen (DEVICEHIGH)
REM Deaktiviert (rem DEVIC...), da nicht notwendig
rem DEVICEHIGH=C:\DOS\DRIVER\SCSI\ASPIDISK.SYS /D

[ASPICD]
REM ----- SCSI ASPI Treiber fuer CD-ROM Unterstuetzung ------------------------
REM SCSI CD-ROM-ASPI-Treiber wird in den hohen Speicherbereich geladen
REM (DEVICEHIGH)
REM Der Devicenamen wird festgelegt (/D:ASPICD0)
DEVICEHIGH=C:\DOS\DRIVER\SCSI\ASPICD.SYS /D:ASPICD0

[IDECD]
REM ----- IDE Treiber fuer CD-ROM Unterstuetzung ------------------------------
REM IDE(ATAPI) CD-ROM-ASPI-Treiber wird in den hohen Speicherbereich geladen
REM (DEVICEHIGH)
REM Der Devicenamen wird festgelegt (/D:IDECD0)
REM
REM Dies ist ein allgemeiner ATAPI-Treiber, welcher fuer die meistens
REM IDE(ATAPI) CD-ROMs funktionieren sollte.
REM
DEVICEHIGH=C:\DOS\DRIVER\SCSI\AOATAPI.SYS /D:IDECD0

[IFSHLP]
REM ----- IFSHLP --------------------------------------------------------------
REM Notwendiger Treiber für Windows 3.11 bzw. MSDOS bei
REM der Verwendung eines Netzwerkes
DEVICE=C:\WIN311\IFSHLP.SYS

[RDISK]
REM ----- RAM-Disk ------------------------------------------------------------
REM RAMDisk-Treiber wird in den hohen Speicherbereich geladen (DEVICEHIGH)
REM Groesse der RAMDisk 3072KB (3072)
REM Verwendet das Extended RAM (/E)
DEVICEHIGH=C:\DOS\RAMDRIVE.SYS 3072 /E

[SPECIAL]
REM ----- Diverses ------------------------------------------------------------
REM Eigentlich unnoetiges Geraffel
REM
DEVICE=C:\DOS\SETVER.EXE
COUNTRY=041,,C:\DOS\COUNTRY.SYS
DEVICE=C:\DOS\DISPLAY.SYS CON=(EGA,,1)

[PNP]
REM ----- PnP Treiber ---------------------------------------------------------
REM ISA PnP-treiber für eine SoundBlaster Karte
DEVICE=C:\DOS\PNP\DRIVERS\DOS\DWCFGMG.SYS

[WIN311]
REM ----- Win 3.11 ------------------------------------------------------------
REM Smartdive-Treiber (Plattencache)
REM Für SCSI-Platten wird die Option Double Buffer empfohlen
REM REM (/DOUBLE_BUFFER)
DEVICE=C:\WIN311\SMARTDRV.EXE /DOUBLE_BUFFER

REM ***** Ende der Definitionen der INCLUDE Zeilen ****************************


REM ***** Definition der eigentlichen Configs der Menus ***********************
REM Hier werden mithilfe der Include Zeilen, die aktiven Konfigurationen
REM zusammengestellt.
REM

[MSDOS0S]
include=HIMEM
include=NOEMS
include=ASPI
include=ASPICD

[MSDOS1S]
include=HIMEM
include=EMS
include=ASPI
include=ASPICD

[MSDOS2S]
include=HIMEM
include=NOEMS
include=ASPI
include=ASPICD
include=IFSHLP

[WINS]
include=HIMEM
include=NOEMS
include=ASPI
include=ASPICD
include=IFSHLP
include=WIN311

[MSDOS0I]
include=HIMEM
include=NOEMS
include=IDECD

[MSDOS1I]
include=HIMEM
include=EMS
include=IDECD

[MSDOS2I]
include=HIMEM
include=NOEMS
include=IDECD
include=IFSHLP

[MSDOS3I]
include=HIMEM
include=EMS
include=IDECD

[WINI]
include=HIMEM
include=NOEMS
include=IDECD
include=IFSHLP
include=WIN311

[COMMON]
REM ----- Allgemeine Einstellungen --------------------------------------------
REM Alle Konfigurationen (sprich Menupunkte) führen nach Ihren
REM Kommandos, die hier aufgeführten Befehle aus.
REM
REM Kommando Interpreter COMMAND.COM wird geladen
REM Speicher für die Umgebungsvariablen wird auf 1024Byte festgelegt
REM (/E:1024)
REM Der Kommando Interpreter bleibt speicherresident (/p)
REM
REM Sollten man zusätzlichen Speicher benoetigen, so kann man
REM die Werte bei
REM BUFFERS
REM FILES
REM STACKS
REM auf niedrige Werte anpassen.
REM Desweiteren könnte man bei
REM LASTDRIVE
REM einen hoeheren Buchstaben einsetzen; zB. "M"
REM Die dabei anfallenden Einsparungen sind allerdings minimal.
REM
SHELL=C:\COMMAND.COM C:\ /E:1024 /p
BUFFERS=40,0
FILES=40
FCBS=16,0
STACKS=15,512
LASTDRIVE=Z